Excel VBA コンボボックスとセル範囲の連携を再設定する

'重複をチェックして設定値をワークシートに書き込む
Private Sub cmdSave_Click()
    Dim eRow As Long    '最終行
    Dim i As Long       'ループカウンター用
    Dim rng1 As Range, rng2 As Range 'セル範囲
    Dim strSet As String    'Key文字列（A+B+C+D）
    Dim strName As String   '名称文字列（B列）
    Dim re As Long
    Call cmdPW_Click    'PW生成する
    With Worksheets("設定値")
        eRow = .Cells(Rows.Count, 2).End(xlUp).Row + 1
        strName = Cmb1.Text & Cmb2.Text
        If strName = "" Then MsgBox "「名称」がありません！": Exit Sub
        strSet = Cmb1.Text & Cmb2.Text & Cmb3.Text & Cmb4.Text
        If strSet = "" Then MsgBox "「Key」がありません！": Exit Sub
        Set rng1 = Range(.Cells(2, 5), .Cells(eRow, 5))
        '同じItemが存在するかチェックする
        For i = 1 To rng1.Count
            If rng1(i).Value = strSet Then
                MsgBox "重複データのため登録しませんでした！"
                Exit Sub
            End If
        Next
        'Keyに重複が無かった場合、分類+名称で再チェック
        Set rng1 = Range(.Cells(2, 1), .Cells(eRow, 1))
        Set rng2 = Range(.Cells(2, 2), .Cells(eRow, 2))
        '同じ名称が存在するかチェックする
        For i = 1 To rng1.Count
            If rng1(i).Value & rng2(i).Value = strName Then
                re = MsgBox("同じ名称があります！書き換えますか？", _
                                        vbYesNo + vbExclamation)
                If re = vbYes Then
                    'データを上書きさせるため
                    eRow = i + 1 'eRowにセルの行番号を代入
                Else: Exit Sub
                End If
            End If
        Next
        '指定セルにデータを書き込む（追加は最下部）
        .Cells(eRow, 1).Value = Cmb1.Text
        .Cells(eRow, 2).Value = Cmb2.Text
        .Cells(eRow, 3).Value = Cmb3.Text
        .Cells(eRow, 4).Value = Cmb4.Text
        .Cells(eRow, 5).Value = strSet
    End With
End Sub

'テキスト部の文字列を重複せずにItemに登録
Private Sub Cmb2_Enter()
    Call Cmb_Enter(Cmb2)
End Sub

'テキスト部の文字列を重複せずにItemに登録
Sub Cmb_Enter(cmbNo As ComboBox)
    Dim i As Long       'ループカウンター用
    Dim flg As Boolean  '重複チェック用フラグ
    With cmbNo
        If .Text = "" Then Exit Sub
        '同じItemが存在するかチェックする
        For i = 0 To .ListCount - 1 'Listは0から始まるので
            If .List(i) = .Text Then
                flg = True  '存在時はflgをTrueに
                Exit For    'ループを抜ける
            End If
        Next
        'flgがFalseの場合は登録する
        If flg = False Then .AddItem .Text
    End With
End Sub