VBA Parentを使ったらUserFormを完全復元できた

'シートに保存したプロパティ値からユーザーフォームを作成する
Sub UserFormAdd()
    Dim Frm As VBIDE.VBComponent    'UserForm用
    Dim mCtrl As MSForms.Control    'MultiPage用
    Dim fCtrl As MSForms.Control    'Frame用
    Dim Ctrl As MSForms.Control     '配置コントロール用
    Dim PVal As Variant             '設定値保存配列変数
    Dim r As Long                   '行数取得保存用
    Dim c As Long                   '最終列保存用
    Dim X As Long, Y As Long        '配列ループ処理用
    Dim i As Long, j As Long        'ループ処理用変数
    Dim P As Long                   'Pages(Index)用
    Dim chk As Long                 'Page数チェック用
    Dim ctrlName As String          'コントロール名
    Dim cName As String             'Addメソッド引数用
    Dim pName As String             'Parent名
    Dim pIndex As Long              'Pages(Index)取得用
    Dim wb As Workbook, sh As Worksheet
    Set wb = ActiveWorkbook
    Set sh = wb.Worksheets("Ctrl_SetValue") '設定値保存シート
    
    r = sh.Cells(Rows.Count, 1).End(xlUp).Row   'UserForm設定値の最終行取得
    ReDim PVal(1 To r, 1 To 2)      '２次元配列初期化
    'シートに保存した設定値を配列に保存する
    For Y = 1 To r                  '行数分のループ
        For X = 1 To 2              '列数分のループ
            PVal(Y, X) = sh.Cells(Y, X) 'セルからプロパティ設定を取得
        Next X
    Next Y
   'ユーザフォームを追加
    Set Frm = ThisWorkbook.VBProject.VBComponents.Add(vbext_ct_MSForm)
    On Error Resume Next    '設定できない場合エラーでストップしないように
    With Frm
        .Name = PVal(2, 2)  'オブジェクト名だけ先に設定
        For i = 3 To r
            .Properties(PVal(i, 1)) = PVal(i, 2)  'UserFormのプロパティ値セット
        Next i
        '取得保存データの最終列取得
        c = sh.Cells(1, Columns.Count).End(xlToLeft).Column
        'プロパティー保存最終行取得（３列目から）
        r = sh.Cells(Rows.Count, 3).End(xlUp).Row
        P = 0   'Pages(Index)用変数の初期化（0から始まる）
        For j = 4 To c  '3列目がプロパティ名なので4列目からが設定値
            'シートに保存した設定値を（関数で）配列に読み込む
            PVal = ReadPROP(r, j, sh)
            ctrlName = PVal(1, 2)                   'コントロール名(Type)
            cName = "Forms." & ctrlName & ".1"      'Addメソッドに渡す引数
            pName = PVal(3, 2)                      'Parent親オブジェクト名
            'コントロールのTYPEで処理を分岐
            Select Case True
                Case ctrlName Like "MultiPage*"     'MultiPageの場合
                    '親オブジェクトを確認して配置
                    Select Case True
                        Case pName Like "Page*"     'Pageの場合
                            pIndex = PagesIndex(mCtrl, pName) 'PageのIndexを取得
                            Set mCtrl = mCtrl.Pages(pIndex).Controls.Add(cName)
                        Case pName Like "Frame*"    'Frame内に配置
                            Set mCtrl = fCtrl.Controls.Add(cName)
                        Case Else                   'UserFormに配置
                            Set mCtrl = .Designer.Controls.Add(cName)
                    End Select
                    For i = 2 To r  'コントロールのプロパティ値設定
                        Call setPVal(PVal(i, 1), mCtrl, PVal(i, 2))
                    Next i
                    'Page数をチェックして不足分を追加する
                    chk = PVal(r, 2)   'chk = Pageの数
                    For i = 1 To chk - 2
                        mCtrl.Pages.Add
                    Next i
                Case ctrlName Like "Page*"          'Pageの場合
                    For i = 2 To r  'Pageのプロパティ値設定処理
                        If PVal(i, 2) <> "" Then 'PageではNULLの場合処理しない
                            Call setPVal(PVal(i, 1), mCtrl.Pages(P), PVal(i, 2))
                        End If
                    Next i
                    P = P + 1   'PageのIndexをカウントアップ
                Case ctrlName Like "Frame*"         'Frameの場合
                    Select Case True '親オブジェクトの種類で処理を分岐
                        Case pName Like "Page*"
                            pIndex = PagesIndex(mCtrl, pName)
                            'Pageにコントロール設置
                            Set fCtrl = mCtrl.Pages(pIndex).Controls.Add(cName)
                        Case pName Like "Frame*"
                            Set fCtrl = fCtrl.Controls.Add(cName)
                        Case Else   'UserFormに配置
                            Set fCtrl = .Designer.Controls.Add(cName)
                    End Select
                    For i = 2 To r  'コントロールのプロパティ値設定
                        Call setPVal(PVal(i, 1), fCtrl, PVal(i, 2))
                    Next i
                'ListViewの場合
                Case ctrlName Like "ListView*"
                    'ListViewの場合はFormsではなくMSComctlLibに変更
                    cName = "MSComctlLib.ListViewCtrl.2"
                    '親オブジェクトの種類で処理を分岐
                    Select Case True
                        Case pName Like "Page*"
                            pIndex = PagesIndex(mCtrl, pName)
                            'Pageにコントロール設置
                            Set Ctrl = mCtrl.Pages(pIndex).Controls.Add(cName)
                        Case pName Like "Frame*"
                            Set Ctrl = fCtrl.Controls.Add(cName)
                        Case Else   'UserFormに配置
                            Set Ctrl = .Designer.Controls.Add(cName)
                    End Select
                    For i = 2 To r  'コントロールのプロパティ値設定
                        Call setPVal(PVal(i, 1), Ctrl, PVal(i, 2))
                    Next i
                'その他のコントロール
                Case Else
                    '親オブジェクトの種類で処理を分岐
                    Select Case True
                        Case pName Like "Page*"
                            pIndex = PagesIndex(mCtrl, pName)
                            'Pageにコントロールを配置
                            Set Ctrl = mCtrl.Pages(pIndex).Controls.Add(cName)
                        Case pName Like "Frame*"
                            'Frameにコントロールを配置
                            Set Ctrl = fCtrl.Controls.Add(cName)
                        Case Else   'UserFormに配置
                            Set Ctrl = .Designer.Controls.Add(cName)
                    End Select
                    For i = 2 To r  'コントロールのプロパティ値設定
                        Call setPVal(PVal(i, 1), Ctrl, PVal(i, 2))
                    Next i
            End Select
        Next j
    End With
    On Error GoTo 0
    Set Ctrl = Nothing
    Set fCtrl = Nothing
    Set mCtrl = Nothing
    Set Frm = Nothing
    Set sh = Nothing
    Set wb = Nothing
End Sub

'Pageオブジェクト名からPagesインデックスを取得する
Private Function PagesIndex(ByVal mCtrl As Object, pName As String) As Long
    Dim i As Long
    'MultiPageオブジェクトからPage数をカウントして調べる
    For i = 0 To mCtrl.Pages.Count - 1
        If mCtrl.Pages(i).Name = pName Then
            PagesIndex = i
            Exit For
        End If
    Next i
End Function

'設定値保存シートの指定列から値を取得して配列に保存する
Private Function ReadPROP(ByVal r As Long, j As Long, sh As Worksheet) As Variant
    Dim Y As Long
    Dim PVal As Variant  '配列用変数

    ReDim PVal(1 To r, 1 To 2)   '2次元配列初期化
    'シートに保存した設定値を配列に読み込む
    For Y = 1 To r
        PVal(Y, 1) = sh.Cells(Y, 3)  'プロパティ名
        PVal(Y, 2) = sh.Cells(Y, j)  'プロパティ値
    Next Y
    ReadPROP = PVal     '関数に配列を渡す
End Function