どうしても消せない Excel の「入力規則」外部リンク切れエラー!
前回記事の継続で、ExcelファイルのZIP化から リンク切れエラー「定義」を強制削除してExcelファイルに復元するまでをVBAで自動化してみました。自分用に作成したツールですがよかったらご覧ください。
【2026年11月 更新】64ビット版のExcelでも動くように、ZIPの解凍と圧縮を 7-ZIP32.DLL から Windows 標準の tar コマンドに変更しました。DLLのインストールは不要になりました。
くるみこ今回も、あくまで自分用に設定してみたツールの紹介です!
もし、試してみようと思われた方は、自己責任で行ってくださいね!
必ず事前にバックアップを取ってから試してください!

消せない外部リンクエラーを自動で強制削除してくれるツールということですね。
ZIPファイルの操作を組み入れていくんですね(^^♪
初めに、この記事で紹介している方法でブレイクリンクしておきましょう。
※この記事のサンプルファイルにはこの機能も付いています。

それでも消せないリンクが残った場合に、どうしたらよいかという記事は次の記事でした。ただし、すべて手動で行う必要があります。

さらに、
手動でエラーリンクを探すかわりにVBAでファイルのエラー数を見るツールの記事 や
Excel VBA 消せない入力規則外部リンクエラーの削除ツールの記事を掲載してきました。
どうせなら、対象のExcelファイルの拡張子をZIPに変更して解凍 → エラー削除 → ZIP化して拡張子をエクセルに戻すという一連の流れをVBAで全部自動化してみたいと思います。(あくまで自分用として)
【この記事でわかることは】
・消せない「入力規則」外部リンクエラーの強制削除をVBAで自動実行する方法
・Name ステートメントを使ってファイルの拡張子変更方法
・FileSystemObject の DeleteFolder メソッドの使用方法
それでは、やってみましょう。
まず動作設定を検討しました
動作のおおまかな流れを次のように決めました。
【前提として】ブレイクリンクで解除可能なエラーリンクを削除しておきます。これで消すことができなかった外部リンクが残っている場合に実行します。
実行には、7-ZIP32.DLL が必要です。インストールされていない場合は、統合アーカイバプロジェクトから7-ZIP32.DLL for windows 32bitsをダウンロードしてください。
7-ZIP32.DLL は、基本的には System フォルダに入れますが、入れられない場合はExcelファイルと同じフォルダに入れておいてください。
ZIPの解凍と圧縮には、Windows 10 以降に標準で入っている tar コマンドを使います。追加でインストールするものはありません。Declare 文(DLLの宣言)を使っていないので、32ビット版・64ビット版のどちらのExcelでもそのまま使えます。【2026年11月 追記】
設定したVBAコード
対象のExcelファイルをダイアログから選択するだけで強制解除が完了する設定です。
'*******************************************
'* 対象のExcelファイル選択するだけで解除完了
'*******************************************
Sub TargetFileSelect()
Dim tgfullpath As String
Dim strPath As String
Dim zipFullName As String
Dim zFileName As String
Dim re As Long, lrow As Long
re = MsgBox("ファイルのサイズによっては処理に時間がかかります!" _
, vbInformation + vbOKCancel)
If re = vbCancel Then Exit Sub
'ファイルをダイアログから選択します
With Application.FileDialog(msoFileDialogFilePicker)
.AllowMultiSelect = False '複数選択不可
.Filters.Clear 'フィルタを初期化してセット
.Filters.Add "Microsoft Excelファイル", "*.xls?"
.FilterIndex = 1
.InitialFileName = ThisWorkbook.Path '初期表示フォルダの設定
If .Show = False Then
MsgBox "ファイルが選択されませんでした!", vbExclamation
Exit Sub
Else
'選択された場合
tgfullpath = .SelectedItems(1)
End If
End With
'確認画面非表示とカーソル設定
Application.DisplayAlerts = False
Application.Cursor = xlWait
'Nameステートメントで選択ファイル名に拡張子「.zip」を付加
zipFullName = tgfullpath & ".zip"
Name tgfullpath As zipFullName 'ここで拡張子付加
zFileName = Dir(zipFullName) 'zipファイル名取得
'作業用フォルダ"work"を作成する
strPath = Replace(zipFullName, zFileName, "") & "work"
If Dir(strPath, vbDirectory) = "" Then
MkDir strPath
End If
'-------------------------------------------
'ZIPの解凍処理へ(解凍先フォルダ、ZIPファイル、PW)
Call DeCompUNZIP(strPath, zipFullName, "")
'-------------------------------------------
'見出しを除きシートの書き出し範囲をクリアする
lrow = Cells(Rows.count, 12).End(xlUp).Row
If lrow > 1 Then Range(Cells(2, 11), Cells(lrow, 12)).ClearContents
'解凍後のワークシートXMLエラー削除処理へ
Call ReCall(strPath & "\xl\worksheets")
'-------------------------------------------
'ZIPの圧縮処理へ
Call CompressZIP(strPath & "\*", zipFullName, "")
'-------------------------------------------
'拡張子.zipを消して元の拡張子に戻す
Name zipFullName As tgfullpath
'FSOで作業フォルダ全削除
Dim fso As Object
Set fso = CreateObject("Scripting.FileSystemObject")
fso.DeleteFolder (strPath)
Set fso = Nothing
MsgBox "処理が完了しました。ファイルを確認してください!", vbInformation
'確認画面とカーソルを戻す
Application.DisplayAlerts = True
Application.Cursor = xlDefault
End Subコードを簡単に解説します。
・11行目、サイズが大きい場合処理に時間がかかるのでメッセージ表示(Cancelで中止)
・16~29行目で、ファイルダイアログを表示、選択ファイルを変数に代入
・32行目、確認画面を非表示に設定
・33行目、実行中はカーソルをWait表示に設定
・36~37行目は、Name ステートメントで取得したファイル名の後ろに「.zip」を付加
・41~44行目で、解凍先として作業フォルダ「work」を作成しています。
・48行目、ZIPの解凍処理を呼び出して「work」に解凍します。
・55行目、解凍後 work\xl\worksheets フォルダ内ファイル(sheet*.xml)をすべて処理するため「再帰処理」プロシージャに処理を渡しています。(この部分は次の項で説明)
・59行目、エラー定義の解除処理完了後、再びZIPファイル化するため ZIPの圧縮処理を呼び出しています。
・63行目、Name ステートメントで出来上がったZIPファイル(拡張子「.zip」)を元のファイル名に戻しています。
・66~69行目は、 FileSystemObject オブジェクトの DeleteFolder で「work」フォルダ(内のすべて)を削除しています。
・74、75行目で、画面表示とカーソルを元に戻しています。
フォルダ内の全ファイルを調べるための再帰処理コード
サブフォルダまで含めて全ファイルを処理するために再帰処理内から削除処理を呼び出します。
「再帰処理」については過去の記事でも紹介していますのでリンク先を参照してください。
'サブフォルダ内も含めてファイルを調べる(再帰処理)
Sub ReCall(sPath As String)
Dim buf As String
Dim f As Object
buf = Dir(sPath & "\*.*")
Do While buf <> ""
'ファイル内文字列削除処理呼び出し
Call ReplaceStrFile(sPath & "\" & buf, 0)
buf = Dir() '次のファイル
Loop
'再帰処理
With CreateObject("Scripting.FileSystemObject")
For Each f In .GetFolder(sPath).SubFolders
Call ReCall(f.Path) '再帰
Next f
End With
End Sub・9行目の Call ReplaceStrFile(sPath & “\” & buf, 0) で削除処理へファイルパスを渡しています。
ReplaceStrFile については、前回記事のコードを参照願います。
または、この記事のサンプルをダウンロードして参照してください。
前回記事と変更している点は、引数を増やしている点です。
これは、処理ごとにメッセージを表示させないようにするためのフラグとしています。
「0」の場合はメッセージを出さないように ReplaceStrFile のコードを変更しています。
ZIP(Windows標準のtar)の処理コード
「解凍」「圧縮」に使用するために必要なコードに絞っています。
以前は 7-zip32.dll を使っていましたが、64ビット版のExcelでは動かないため、Windows 標準の tar コマンドに変更しました。関数名と引数は元のままなので、メインのコードは変えずに使えます。
7-zip32.dll については過去の記事で詳しく解説していますのでリンクから参照願います。
Option Explicit
Public strcmd As String
'///////////////////////////////////////////////////////////////////
'ZIPファイルを解凍(Windows標準のtarを使用)
'引数 szUnzipPath:解凍先のフォルダーのパス
' szZIPName:ZIPファイルのパス
' szPWord:パスワード(tarでは使用しません)
'返り値 成功したら True、失敗したらFalse
Public Function DeCompUNZIP(szUnzipPath As String, szZIPName As String, _
Optional szPWord As String = "") As Boolean
If Dir(szUnzipPath, vbDirectory) = "" Then MkDir szUnzipPath
DeCompUNZIP = RunTar("-xf " & dq(szZIPName) & " -C " & dq(szUnzipPath)) = 0
End Function
'///////////////////////////////////////////////////////////////////
'ZIPファイルを作成(Windows標準のtarを使用)
'引数 szTgPath:圧縮するフォルダーのパス(末尾の「\*」付き)
' szZIPName:ZIPファイルのパス
' szPWord:パスワード(tarでは使用しません)
'返り値 成功したら True、失敗したらFalse
Public Function CompressZIP(szTgPath As String, szZIPName As String, _
Optional szPWord As String = "") As Boolean
Dim szDir As String, buf As String, szItems As String
szDir = Left(szTgPath, InStrRev(szTgPath, "\") - 1)
'フォルダー直下のファイルとフォルダーを列挙する
buf = Dir(szDir & "\*", vbDirectory + vbHidden + vbSystem)
Do While buf <> ""
If buf <> "." And buf <> ".." Then szItems = szItems & " " & dq(buf)
buf = Dir()
Loop
'元のZIPファイルは名前を変えて残しておく
If Dir(szZIPName) <> "" Then Name szZIPName As szZIPName & ".bak"
CompressZIP = RunTar("-a -cf " & dq(szZIPName) & " -C " & dq(szDir) & szItems) = 0
If Dir(szZIPName & ".bak") <> "" Then
If CompressZIP Then
Kill szZIPName & ".bak" '成功したら元のZIPファイルを削除
Else
'失敗したら元のZIPファイルに戻す
If Dir(szZIPName) <> "" Then Kill szZIPName
Name szZIPName & ".bak" As szZIPName
End If
End If
End Function
'///////////////////////////////////////////////////////////////////
'tar.exeを実行して終了を待つ(戻り値 正常終了= 0)
Private Function RunTar(szArgs As String) As Long
RunTar = CreateObject("WScript.Shell").Run("tar.exe " & szArgs, 0, True)
If RunTar <> 0 Then MsgBox "tarの実行でエラーが発生しました(" & RunTar & ")"
'ログ用に実行したコマンドを保存
strcmd = strcmd & vbCrLf & "tar.exe " & szArgs
End Function
'///////////////////////////////////////////////////////////////////
'ダブルクォーテーション付加
Public Function dq(ByVal Text As String) As String
dq = """" & Replace(Text, """", """""") & """"
End Functionコードを簡単に解説します。
・DeCompUNZIP は「tar -xf ZIPファイル -C 解凍先」で、ZIPファイルを作業フォルダに解凍します。
・CompressZIP は、作業フォルダ直下のファイルとフォルダを並べて「tar -a -cf ZIPファイル -C 作業フォルダ ファイル…」で圧縮します。「-a」を付けると、拡張子「.zip」からZIP形式で作成してくれます。
・tar は既存のZIPファイルに追加できないので、元のZIPファイルの名前を「.bak」に変えてから作り直しています。圧縮に失敗した場合は元のZIPファイルに戻すので、対象のExcelファイルは変更されません。
・RunTar は、WScript.Shell の Run メソッドで tar.exe を画面に表示せずに実行し、終わるまで待ちます。戻り値が0以外の場合はエラーです。
・tar はパスワード付きZIPに対応していないので、引数 szPWord は使っていません(元のコードと同じ形で呼び出せるように残しています)。
解除後のExcelファイルを開いてみる
エラー強制解除を実行した後のExcelファイルを開く際に、次のようなダイアログが表示される場合があります。
こんな感じのメッセージ

かまわず「はい」を選択すると、次のメッセージが!

それでも、Excelファイルを開いてみた結果は、エラーリンクが無くなっていて問題なく動作しました。
おそらく、削除した部分に関連している計算式があったりしたものが、設定が削除されたために発出されたメッセージではないでしょうか?
十分とは言えませんが、いろいろなケースでテストした結果、復元後のExcelファイルはおおむね問題なく動作しました。
tar版に変更した後も、64ビット版のExcelで、参照切れの入力規則だけが削除され、ほかの入力規則はそのまま残ることを確認しています。
万一、不具合があった場合でもバックアップを取っていれば問題ないと思いますので、是非試してみていただければと思います。
★ 自分専用ですが、ワークシートXML内の「入力規則」のエラー定義削除は自動解除できるようになりました(^^♪
まとめ(おわりに)
以上、Excelのどうしても消せない「入力規則」x14:dataValidation の外部リンクエラーを強制的に自動解除するVBAの解説でした。
サンプルファイルをダウンロードできるように登録していますので是非お試しください。
ただし、使用にあたっては自己責任でお願します。
まとめと感想など
くるみこ「入力規則」の外部リンクエラーをVBAで自動削除してしまうコードの解説でした。あくまで、個人用に作ってみたものです。いかがでしたか?
検証が十分とは言えませんが、もしよかったらお試しくださいませ。

今回は、Name ステートメントを使ってファイル名の変更やフォルダ移動ができることがわかりました(^^)/ バックアップを取ってから実行!ですね(^^ゞ
- 消せない「入力規則」外部リンクエラーの強制削除をVBAで自動実行する手順
- Name ステートメントを使ったファイル名変更で拡張子も変更する方法
- FileSystemObject の DeleteFolder メソッドでフォルダをそっくり削除する方法
【今後の記事について】
今回の記事はいかがだったでしょうか。皆さまのお役に立てたなら幸いです(^^;
「汎用でだれでも使えて活用できるように考えてる」というポリシーで、記事を継続して書いていきたいと思っています。どうぞよろしくお願いしますm(_ _)m
【検討中の今後の記事内容は・・・・】
・実務に役立つものを提供できるよう常に検討しています(^^ゞ
・その他雑記的に「プチネタなど」もいろいろ考えていきたいと思っています・・・・
・今後の記事にご期待ください(^^)/
※1回買えば複数サイトで使い回しOK
過去記事のサンプルファイルをダウンロードできます
今回記事のサンプルファイルをこのリンク先に登録しています!
過去の記事で使用したサンプルファイルをダウンロードできるようにページを設置していますので、こちら(このリンク先)からご利用ください


