VBA Partition関数 数値を範囲で分類し文字列で返す

'■Partition関数サンプル01（戻り値の文字列を確認）
Sub Partition_Sample_01()
  Dim str As String
  str = Partition(25, 0, 100, 10)  '結果: " 20: 29"
  Debug.Print str
  str = Partition(5, 0, 100, 10)   '結果: "  0:  9"
  Debug.Print str
  str = Partition(105, 0, 100, 10) '結果: "101:   "
  Debug.Print str & "（最大値超え）"
  str = Partition(-5, 0, 100, 10)  '結果: "   : -1"
  Debug.Print str & "（開始値未満）"
End Sub

'■Partition関数サンプル02（セルの点数をランク付け）
Sub Partition_Sample_02()
  Dim er As Long      'データ最終行用
  Dim i As Long       'ループ用
  Dim score As Long   '点数用
  Dim rStr As String  '範囲文字列用
  Dim rank As String  'ランク文字列用
  Dim wr As Long: wr = 2 '書き込み行初期値
  'データの最終行を取得
  er = Cells(Rows.Count, "A").End(xlUp).Row
  '点数(B列)データをループ処理で取得
  For i = 2 To er
    score = Cells(i, 2).Value
    '範囲名を取得（0点～100点まで、20刻み）
    rStr = Partition(score, 0, 100, 20)
  
    'C・D列に結果を出力
    Select Case rStr  '範囲名をランク名に変換
      Case "  0: 19": rank = "Eランク"
      Case " 20: 39": rank = "Dランク"
      Case " 40: 59": rank = "Cランク"
      Case " 60: 79": rank = "Bランク"
      Case " 80: 99": rank = "Aランク"
      Case "100:100": rank = "Sランク"
      Case Else: rank = "----"
    End Select
    Cells(wr, 3) = rank    'ランク名
    Cells(wr, 4) = rStr    '範囲文字列
    wr = wr + 1
  Next i
  MsgBox "集計が完了しました！"
End Sub