VBA コンボボックスの使い方と文字列縦上下中央揃えも実現

'コンボボックスのEnterイベント
Private Sub Cmb1_Enter()
    With Cmb1
        If .Text <> "" Then
            .AddItem .Text
        End If
    End With
End Sub

'テキスト部の文字列を重複せずにItemに登録
Private Sub Cmb1_Enter()
    Dim i As Long       'ループカウンター用
    Dim flg As Boolean  '重複チェック用フラグ
    With Cmb1
        If .Text = "" Then Exit Sub
        '同じItemが存在するかチェックする
        For i = 0 To .ListCount - 1 'Listは0から始まる
            If .List(i) = .Text Then
                flg = True  '存在時はflgをTrueに
                Exit For    'ループを抜ける
            End If
        Next
        'flgがFalseの場合は登録する
        If flg = False Then .AddItem .Text
    End With
End Sub

'設定値をワークシートに書き込む
Private Sub cmdSave_Click()
    Dim eRow As Long
    With Worksheets("設定値")
        eRow = .Cells(Rows.Count, 1).End(xlUp).Row + 1
        .Cells(eRow, 1).Value = Cmb1.Text
        .Cells(eRow, 2).Value = Cmb2.Text
        .Cells(eRow, 3).Value = txtSet3.Value
        .Cells(eRow, 4).Value = txtPW.Value
    End With
End Sub

'設定値をワークシートに書き込む
Private Sub cmdSave_Click()
    Dim eRow As Long
    Dim i As Long       'ループカウンター用
    Dim flg As Boolean  '重複チェック用フラグ
    Dim rng As Range
    Dim strSet As String
    strSet = Cmb1.Text & Cmb2.Text & txtSet3.Text
    With Worksheets("設定値")
        eRow = .Cells(Rows.Count, 1).End(xlUp).Row + 1
        Set rng = Range(Cells(2, 4), .Cells(eRow, 4))
        If strSet = "" Then Exit Sub
        '同じItemが存在するかチェックする
        For i = 1 To rng.Count
            If rng(i).Value = strSet Then
                flg = True  '存在時はflgをTrueに
                Exit For    'ループを抜ける
            End If
        Next
        'flgがFalseの場合は登録する
        If flg = False Then
            .Cells(eRow, 1).Value = Cmb1.Text
            .Cells(eRow, 2).Value = Cmb2.Text
            .Cells(eRow, 3).Value = txtSet3.Value
            .Cells(eRow, 4).Value = strSet
        Else
            MsgBox "重複データのため登録しませんでした！"
        End If
    End With
End Sub

Private Sub UserForm_Initialize()
    'TextBoxをイニシャライズするプロシージャを呼び出す
    Call TextBox_Initialize
    'ComboBoxのItemをセットするプロシージャを呼び出す
    Call cbmBox_ItemSet
End Sub

'ComboBoxのアイテムをセットする
Sub cbmBox_ItemSet()
    Dim eRow As Long
    Dim i As Long, j As Long
    eRow = Worksheets("設定値").Cells(Rows.Count, 1).End(xlUp).Row
    Dim Dic As Object, Keys As Variant
    Dim Item As Variant, Items As Variant
    Dim cmbNo() As Variant      'ComboBox用
    Dim ctl As Control          'コントロール用
    Dim ncmb As Long            'ComboBox用カウンター
    '配列初期化
    ReDim Preserve cmbNo(0)
    For Each ctl In fmPW_Make.Controls
        If TypeOf ctl Is msforms.ComboBox Then
            ncmb = ncmb + 1
            '配列に要素を追加（コントロール）
            ReDim Preserve cmbNo(ncmb)
            Set cmbNo(ncmb) = ctl
        End If
    Next
    For j = 1 To ncmb
        '重複登録できないDictionaryオブジェクトを利用する
        Set Dic = CreateObject("Scripting.Dictionary")
        With Worksheets("設定値")
            Items = .Range(.Cells(2, j), .Cells(eRow, j)).Value
        End With
        On Error Resume Next    '同一データ時のエラー回避用
        For Each Item In Items
            If Not Item = Empty Then    '空白は登録しない
                Dic.Add Item, Item
            End If
        Next
        On Error GoTo 0
        Keys = Dic.Keys
        For i = 0 To Dic.Count - 1
            cmbNo(j).AddItem Keys(i) 'リストにItemを登録する
        Next i
        Set Dic = Nothing
    Next j
End Sub

'最初（表示前）に実行される
Private Sub UserForm_Initialize()
    'TextBoxをイニシャライズするプロシージャを呼び出す
    Call TextBox_Initialize
    'ComboBoxをイニシャライズするプロシージャを呼び出す
    Call ComboBox_Initialize
    'ComboBoxのItemをセットするプロシージャを呼び出す
    Call cbmBox_ItemSet
End Sub

'ComboBoxをイニシャライズする
Sub ComboBox_Initialize()
    Dim dmyL As msforms.Label   'ダミーのラベル作成用
    Dim i As Long
    Dim cmbNo() As Variant     'TextBox用
    Dim ncmb As Long            'TextBox用カウンター
    Dim ctl As Control          'コントロール用
    '配列初期化
    ReDim Preserve cmbNo(0)
    For Each ctl In fmPW_Make.Controls
        If TypeOf ctl Is msforms.ComboBox Then
            ncmb = ncmb + 1
            '配列に要素を追加（コントロール）
            ReDim Preserve cmbNo(ncmb)
            Set cmbNo(ncmb) = ctl
        End If
    Next
    For i = 1 To ncmb
        'ダミーラベルを追加
        Set dmyL = fmPW_Make.Controls.Add("Forms.Label.1")
        With cmbNo(i)
            .Font.Size = 11     'フォントサイズ指定
            .Height = .Font.Size + 10   '高さ調整
'            .MultiLine = False 'このプロパティは無い
            'TextBoxのプロパティをラベルに適用させる
            dmyL.Top = .Top
            dmyL.Left = .Left
            dmyL.Height = .Height
            dmyL.Width = .Width
            dmyL.BackColor = .BackColor '背景色
            'TextBox風のエフェクトに
            dmyL.SpecialEffect = fmSpecialEffectSunken
            dmyL.ZOrder 1 '1=fmBottom 最背面に表示(0=fmTopで最前面)
            'TextBoxのプロパティ調整
            .SpecialEffect = fmSpecialEffectFlat 'フラットに変更
            .Width = .Width - 3     'ラベルの内側になるように
            .Height = .Height - 4   '高さも同様
            .Left = .Left + 1.5     'Widthの3の半分
            .Top = .Top + 3         'ここで表示位置を微調整する
        End With
        Set cmbNo(i) = Nothing
        Set dmyL = Nothing
        Next
End Sub